Re: [de-users] [Calc] umfangreiches Sortieren

Hallo Micha,

Du hast der Funktion FILTERN() zum Vergleich mit "" gleich 4 Spalten zur 
Verfügung gestellt. Das geht so nicht.

Wenn du nur nach einer Spalte Filtern möchtest geht das so. Hier im 
Beispiel Spalte 6.

=FILTERN(
VSTAPELN(
SPALTENWAHL(Bereich1;6;7;3;4);
SPALTENWAHL(Bereich2;6;7;3;4);
SPALTENWAHL(Bereich3;6;7;3;4);
SPALTENWAHL(Bereich4;6;7;3;4);
SPALTENWAHL(Bereich5;6;7;3;4);
SPALTENWAHL(Bereich6;6;7;3;4));
VSTAPELN(
SPALTENWAHL(Bereich1;6);
SPALTENWAHL(Bereich2;6);
SPALTENWAHL(Bereich3;6);
SPALTENWAHL(Bereich4;6);
SPALTENWAHL(Bereich5;6);
SPALTENWAHL(Bereich6;6))<>"")

Brauchst du den Vergleich mit allen Spalten, dann musst du die 
gewünschten Spalten mit & verketten. Dann aber mit LET() sonst müsstest 
du im Filter 4 x den Inhalt von _a eintragen. So ist es nicht so lang.
=LET(
_a;VSTAPELN(
SPALTENWAHL(Bereich1;6;7;3;4);
SPALTENWAHL(Bereich2;6;7;3;4);
SPALTENWAHL(Bereich3;6;7;3;4);
SPALTENWAHL(Bereich4;6;7;3;4);
SPALTENWAHL(Bereich5;6;7;3;4);
SPALTENWAHL(Bereich6;6;7;3;4));
_b;SPALTENWAHL(_a;1)&SPALTENWAHL(_a;2)&SPALTENWAHL(_a;3)&SPALTENWAHL(_a;4);
SORTIEREN(FILTERN(_a;_b<>"")))

Mit freundlichen Grüßen

Jürgen Kirsten


Am 10.09.2026 um 17:51 schrieb Micha Kühn:
> Jetzt habe ich das folgende Problem:
>
> Ich habe meine Bereiche benannt und sie dabei wesentlich größer gewählt
> als es je nötig wäre, sodass jeder der Bereiche auch viele Leerzeilen
> enthält.
>
> Und packe ich diese Bereiche bzw. deren ausgewählte Spalten mit VSTAPELN
> untereinander und möchte mit FILTERN die Leerzeilen herausfiltern
> (später dann noch SORTIEREN):
>
> =FILTERN(VSTAPELN(SPALTENWAHL(Bereich1;6;7;3;4);SPALTENWAHL(Bereich2;6;7;3;4);SPALTENWAHL(Bereich3;6;7;3;4);
> SPALTENWAHL(Bereich4;6;7;3;4);SPALTENWAHL(Bereich5;6;7;3;4);SPALTENWAHL(Bereich6;6;7;3;4));
> VSTAPELN(SPALTENWAHL(Bereich1;6;7;3;4);SPALTENWAHL(Bereich2;6;7;3;4);SPALTENWAHL(Bereich3;6;7;3;4);
> SPALTENWAHL(Bereich4;6;7;3;4);SPALTENWAHL(Bereich5;6;7;3;4);SPALTENWAHL(Bereich6;6;7;3;4))<>"")
>
> (Zeilenumbrüche hier eingebaut zur besseren Lesbarkeit)
>
> Ich erhalte den Fehler #WERT!
>
> Woran könnte das liegen? Ohne den FILTERN-Befehl klappt es, nur habe ich
> dann ganz viele Leerzeilen (die nach dem Sortieren oben stehen. Stünden
> sie unten, würde das nicht stören).
>
> Micha


--
Liste abmelden mit E-Mail an: users+unsubscribe@de.libreoffice.org
Probleme? https://de.libreoffice.org/hilfe-kontakt/mailing-listen/abmeldung-liste/
Tipps zu Listenmails: https://wiki.documentfoundation.org/Netiquette/de
Listenarchiv: https://listarchives.libreoffice.org/de/users/
Datenschutzerklärung: https://www.documentfoundation.org/privacy