Re: [de-users] [Calc] umfangreiches Sortieren

Hallo Micha,

hier noch eine Verbesserung / Kürzung der Formel:
=SORTIEREN(VSTAPELN(SPALTENWAHL($'Tab1'.A2:H5;6;7;3;4);SPALTENWAHL($'Tab2'.A2:H5;6;7;3;4);SPALTENWAHL($'Tab3'.A2:H4;6;7;3;4))) 


Mit freundlichen Grüßen

Jürgen Kirsten


Am 10.09.2026 um 12:45 schrieb Jürgen Kirsten:
> Hallo Micha,
>
> um deine Frage zu beantworten. Ja solch eine Funktion gibt es. Unter 
> anderem kann der XVERGLEICH() das.
> Hier am Beispiel Spalte A.
> =XVERGLEICH("*";A:A;2;-1) liefert die letzte Zeilennummer mit einem 
> Eintrag bevor nur noch leere Zellen kommen. Eine Lücke wird ignoriert.
> =XVERGLEICH("";A:A;-1;-1) liefert die erste Zeilennummer in der Spalte 
> die eine Leere Zelle hat. Wenn danach noch Einträge kommen wird das 
> ignoriert.
> Mit dem 4 Parameter -1 wird von hinten bzw. von unten ausgehend gesucht.
>
> Nochmal zurück zu deiner Ausgangsfrage:
> Du kannst die Bereiche in der Formel exakt auf die richtige Größe 
> einstellen (also aus deinem Beispiel $'Tab1'.F2:F5). Du musst dann, 
> wenn du Daten hinzufügst und möchtest das der Bereich sich automatisch 
> erweitert, zwei Dinge beachten. Bei den Optionen - Calc - Allgemein - 
> muss der Haken bei "Bezüge beim Einfügen von Spalten/Zeilen an den 
> Rändern ausdehnen" gesetzt sein. Und du musst bevor du Daten 
> hinzufügst in der ersten leeren Zeile eine Zeile hinzufügen. Das sieht 
> zunächst so aus als ob das gar nichts bringt. Es erweitert aber den 
> Bereich der Daten. Also in deinem Beispiel in Tab1 auf die 6 klicken 
> dadurch die Zeile markieren, dann Strg  und + drücken. Schon erledigt.
> Wenn du wie gerade erläutert keine überschüssigen Zeilen in deinen 
> Bereichen hast, kannst du bei Verwendung der Formel die ich erstellt 
> habe, auf Filtern und damit auch auf LET verzichten. Die vereinfachte 
> Formel lautet dann:
> {=SORTIEREN(VSTAPELN(HSTAPELN($'Tab1'.F2:F5;$'Tab1'.G2:G5;$'Tab1'.C2:C5;$'Tab1'.D2:D5);HSTAPELN($'Tab2'.F2:F5;$'Tab2'.G2:G5;$'Tab2'.C2:C5;$'Tab2'.D2:D5);HSTAPELN($'Tab3'.F2:F4;$'Tab3'.G2:G4;$'Tab3'.C2:C4;$'Tab3'.D2:D4)))} 
>
>
> Solange sich der Matrixbereich deines Ergebnisses noch nicht 
> automatisch in der Größe anpasst, kannst du diesen leicht mit 
> Tastenkombination und Mausklick anpassen. Zunächst im Matrixbereich 
> die Tastenkombination Strg und / (auf dem Numpad) drücken. Damit 
> markierst du den aktuellen Matrixbereich. Dann mit der Maus das kleine 
> blaue Quadrat in der letzten Zelle des Bereichs klicken und auf die 
> richtige Größe korrigieren.
> Wenn dein Matrixbereich viele Zeilen umfasst - hier noch ein Tipp. 
> Bleibe in der ersten Zelle der Matrix befor du sie mit Strg + / 
> markierst. Drücke dann Hochstellen und Tab. Dadurch springst du in die 
> letzte Zelle der Matrix und kannst das Quadrat verschieben.
>
> Noch eine letzte Anmerkung für heute. Wenn du kein Numpad hast, kannst 
> du bei Extras - Anpassen - Tastatur - der Funktion Matrixformel 
> auswählen eine eigen Tastenkombination zuweisen. Zum Beispiel Strg + 
> Umschalt + 7. Das ist nämlich auch das / Symbol.
>
> Mit freundlichen Grüßen
>
> Jürgen Kirsten
>
>
> Am 09.09.2026 um 20:37 schrieb Micha Kühn:
> > Jürgen Kirsten schrieb:
> >
> > > Hallo Micha,
> > >
> > > diese Formel macht alles zusammen:
> > > =LET(_a;VSTAPELN(HSTAPELN($'Tab1'.F2:F15;$'Tab1'.G2:G15;$'Tab1'.C2:C15;$'Tab1'.D2:D15);HSTAPELN($'Tab2'.F2:F15;$'Tab2'.G2:G15;$'Tab2'.C2:C15;$'Tab2'.D2:D15);HSTAPELN($'Tab3'.F2:F15;$'Tab3'.G2:G15;$'Tab3'.C2:C15;$'Tab3'.D2:D15));_b;FILTERN(_a;SPALTENWAHL(_a;1)<>"");SORTIEREN(_b)) 
> > >
> > >
> > > Leider vergrößert sich der Matrixbereich nicht automatisch wenn Daten
> > > hinzukommen. Das musst du noch von Hand machen. In Version 27.2 wir 
> > > aber
> > > bereits daran gearbeitet.
> > >
> > > Ich habe hier nur bis Zeile 15 abgefragt. Das kannst du natürlich viel
> > > größer machen.
> > Danke euch beiden. @Regina: Nein, die Länge ändert sich in jeder Tabelle
> > immer mal wieder (in beide Richtungen).
> >
> > Gab es nicht eine Funktion, die die letzte Zeile mit Inhalt ermittelt?
> > Ich meine, davon mal gelesen zu haben, habe es aber noch nicht selbst
> > benutzt.
> >
> > Micha


--
Liste abmelden mit E-Mail an: users+unsubscribe@de.libreoffice.org
Probleme? https://de.libreoffice.org/hilfe-kontakt/mailing-listen/abmeldung-liste/
Tipps zu Listenmails: https://wiki.documentfoundation.org/Netiquette/de
Listenarchiv: https://listarchives.libreoffice.org/de/users/
Datenschutzerklärung: https://www.documentfoundation.org/privacy