Re: [pt-br-usuarios] Formatação condicional ou estilo na Tabela Dimanica

Ricardo, se você deseja apenas o efeito zebrado e não deseja usar
formatação condicional então use a macro que enviei na lista, vá em
Ferramentas->Macros->Organizar macros->LibreOffice Basic e adicione uma
nova macro, você escolhe fixá-la no contexto do LibreOffice e ela existirá
sempre ou fixar apenas na planilha e ela se tornará privativa existindo
apenas na planilha aberta. A macro é a seguinte:
REM  *****  LIBREOFFICE BASIC  *****
REM O objetivo dessa função é aplicar cor par/impar para
REM cada linha da tabela. O intuito é evitar enganos por seguir
REM um valor numa determinada linha e pêrde-la de vista.
REM O funcionamento é simples, apenas selecione a área que
REM deseja zebrar e aplique essa macro.
REM Ajuste as variaveis nZebra1 e nZebra2  com as cores desejadas.
REM Autor: Gladiston Hamacker Santana <sirhamacker[@]gmail.com>
Sub ZebrarTabela
  Dim oCurrentSelection As Variant
  Dim oRows As Variant
  Dim oCols As Variant
  Dim oCell  As Variant
  Dim Li As Long
  Dim Ci As Long
  Dim nRow As Long
  ' Uma boa idéia de cores que podem ser usadas, podem ser encontradas nos
sites:
  ' http://www.htmlgoodies.com/tutorials/colors/article.php/3478961
  ' http://erikasarti.net/html/tabela-cores/
  ' http://domingoscsouza.com.br/blog/front-end/tabela-de-cores-html
  ' Valores em hexa devem ser precedidos por &H
  Const nZebra1 = &HFFEFD5  'PapayaWhip #FFEFD5
  Const nZebra2 = &HFFFFE0  'LightYellow #FFFFE0

  oCurrentSelection = ThisComponent.getCurrentSelection()
  If oCurrentSelection.supportsService("com.sun.star.table.CellRange") Then
      oRows = oCurrentSelection.getRows()
      oCols = oCurrentSelection.getColumns()
      For Li = 0 To oRows.getCount()-1
        For Ci = 0 To oCols.getCount()-1
          oCell = oCurrentSelection.getCellByPosition(Ci, Li)
          nRow = oCell.RangeAddress.StartRow
          If (nRow Mod 2) = 0 Then
            oCell.setPropertyValue("CellBackColor", nZebra1)
          Else
            oCell.setPropertyValue("CellBackColor", nZebra2)
          EndIf
        Next Ci
      Next Li
  EndIf
End Sub

Para simplificar a operação, você personaliza sua barra de ferramentas
incluindo um botão para a macro, então selecione a área a ser zebrada e a
zebra será aplicada.
Formatação condicional do jeito que o pessoal mencionou na lista também
funciona, mas como não dá para copiar a formatação condicional de um local
para outro entre as guias ou seguimentos diferentes, você tem sempre que
criá-la novamente. Por isso, eu acho que a zebra por macro, no momento é
uma solução melhor apesar de não conseguir escolher a cor a não ser dentro
da macro.

[]´s e sucesso.



Em 30 de março de 2015 11:42, Ricardo César Weise <rcw.smk@gmail.com>
escreveu:

> Prezados,
>
> Necessito de um auxilio, estou tentando gerar um relatório impresso a
> partir de uma tabela dimanica, mas estou com problemas de formatação.
> Já tentei usar o efeito zebrado pela formatação condicional, mas ao mudar o
> critério de Filtragem na Tabela Dimanica ela volta com o estilo "Padrão"
> novamente.
> Como resolvo este problema ?
>
> --
>
>  Atenciosamente,
>
>  Ricardo César Weise
>
> --
> Você está recebendo e-mails da lista usuarios@pt-br.libreoffice.org
> # Informações sobre os comandos disponíveis (em inglês):
>   mande e-mail vazio para usuarios+unsubscribe@pt-br.libreoffice.org
> # Cancelar sua assinatura: mande e-mail vazio para:
>   usuarios+unsubscribe@pt-br.libreoffice.org
> # Arquivo de mensagens:
> http://listarchives.libreoffice.org/pt-br/usuarios/

-- 
Você está recebendo e-mails da lista usuarios@pt-br.libreoffice.org
# Informações sobre os comandos disponíveis (em inglês):
  mande e-mail vazio para usuarios+unsubscribe@pt-br.libreoffice.org
# Cancelar sua assinatura: mande e-mail vazio para:
  usuarios+unsubscribe@pt-br.libreoffice.org
# Arquivo de mensagens: http://listarchives.libreoffice.org/pt-br/usuarios/