Re: [fr-users] OOo Basic et writer

Bonjour

> Message du 17/11/10 22:03
> De : "Bernard Siaud alias Troumad"
>
> Objet : Re: [fr-users] OOo Basic et writer
>
> Il me faudrait des exemples !

J'y avais bien pensé mais ta demande est relativement imprécise...

Ci-dessous 2 procédures "typiques" en partant de ce que tu nous as
donné comme indications :
- accès à un tableau par son nom
- traitement des lignes/colonnes
- traitement des cellules

Je ne joins pas de document exemple (il suffit qu'il contienne
des tableaux nommés comme il faut...)

option explicit

Sub PysMajTable

dim PysTable as object, PysNumLig as integer, PysCell as object

PysTable = thiscomponent.TextTables.getByName("Tableau2")

' ajout de 3 lignes en fin de tableau

PysTable.Rows.insertByIndex(PysTable.Rows.count, 3)

' boucle sur toutes les lignes pour ajouter
' en colonne 1 la valeur du compteur
' on accède "par position" (colonne, ligne)

for PysNumLig = 0 to PysTable.Rows.count - 1
    PysCell=PysTable.getCellByPosition(0, PysNumLig)
    PysCell.string = PysNumLig
next PysNumLig

End Sub

Sub PysBoucleCell

dim PysDoc as object, PysTable as object, PysCell as object
dim PysNum as integer

PysDoc = thisComponent
PysTable = PysDoc.TextTables.getByName("Tableau1")

' afficher le contenu de toutes les cellules du tableau
' on accède par le nom de la cellule en parcourant le
' tableau de ces noms de la borne inf. à la borne sup.

for PysNum = lbound(PysTable.CellNames) to ubound(PysTable.CellNames)
    PysCell = PysTable.getCellByName(PysTable.CellNames(PysNum))
    print PysCell.string
next PysNum

End Sub



Cordialement
Pierre-Yves


Une messagerie gratuite, garantie à vie et des services en plus, ça vous tente ?
Je crée ma boîte mail www.laposte.net

--
E-mail to users+help@fr.libreoffice.org for instructions on how to unsubscribe
List archives are available at http://fr.libreoffice.org/lists/users/
All messages you send to this list will be publicly archived and cannot be deleted