Re: [de-users] CALC: Mittelwert für Jahr / Monat

Hallo Michael,

am einfachsten ist den Fehler abzufangen mit WENNFEHLER(). Also wenn die 
Formel einen Fehler erzeugen würde, wird die Alternative ganz hinten 
ausgegeben.
=WENNFEHLER(MITTELWERTWENNS($Daten.B$2:B$1440;$Daten.A$2:A$1440;">="&DATUM(A2;B2;1);$Daten.A$2:A$1440;"<"&DATUM(A2;B2+1;1));"n.v.")

Übrigens: Wenn nicht jedes Datum aufgeführt ist, musst du dir Gedanken 
machen, was hier eigentlich der richtige Mittelwert ist. Beispiel: Wenn 
vom 1 - 8 eines Monats 4 Werte vorliegen jeweils mit 1,0. Ist dann der 
Mittelwert 1,0 oder 0,5? Mittelwert ignoriert leere Zellen. Daher habe 
ich in meinem Beispiel, die vermeintlich leeren Zellen am Anfang mit 
Null gefüllt (und bei Extras - Calc - Anzeige - Nullwerte wieder 
ausgeblendet). Du kannst auch leere Zellen als Null interpretieren 
lassen in dem du WERT() einfügst. Hier in dem Beispiel von oben:
{=WENNFEHLER(MITTELWERTWENNS(WERT($Daten.B$2):B$1440;$Daten.A$2:A$1440;">="&DATUM(A2;B2;1);$Daten.A$2:A$1440;"<"&DATUM(A2;B2+1;1));"n.v.")}
Dann aber zwingend wieder als Matrixformel.

Deine Formel mit WENN() weiter unten, würde nicht funktionieren. Wenn 
der abgefragte Wert bereits ein Fehler schmeißt, wird die Abfrage ">0" 
mit einem Fehler #WERT! quittiert, da Calc eine Zahl zum Vergleichen 
erfordert. Mit ISTFEHLER() oder ISTZAHL() würde es funktionieren.

Mit freundlichen Grüßen

Jürgen Kirsten


Am 17.08.2026 um 15:17 schrieb Hessler, Klaus-Michael:
> Danke @Jürgen Kirsten, ganz großartig!
> > hier eine Formel für deine Mittelwerte:
> > =MITTELWERTWENNS($Daten.B$2:B$1471;$Daten.A$2:A$1471;">="&DATUM(A2;B2;1);$Daten.A$2:A$1471;"<"&DATUM(A2;B2+1;1)) 
> Und das
> > Wenn du wie in deinem Beispiel mit JAHR() und MONAT() arbeiten 
> > möchtest,...
> ist dank Deiner Anleitung nicht nötig.
>
> Eine Frage noch: Wenn es in der Datum-Liste Lücken gibt z.B. Urlaub im 
> August, kommt eine Fehlermeldung. Das könnte ich mit einer 
> WENN-Bedingung umgehen z.B.:
> = WENN(
> MITTELWERTWENNS($Daten.B$2:B$1471;$Daten.A$2:A$1471;">="&DATUM(A2;B2;1);$Daten.A$2:A$1471;"<"&DATUM(A2;B2+1;1)) 
> > 0;
> MITTELWERTWENNS($Daten.B$2:B$1471;$Daten.A$2:A$1471;">="&DATUM(A2;B2;1);$Daten.A$2:A$1471;"<"&DATUM(A2;B2+1;1)); 
>
> "n.v.")
>
> Das macht die Formel in CALC schlecht lesbar; kann man die Formel 
> irgendwie "ausklammern" oder einmal hinterlegen, mehrmals nutzen?
>
> Danke und viele Grüße
> Michael


--
Liste abmelden mit E-Mail an: users+unsubscribe@de.libreoffice.org
Probleme? https://de.libreoffice.org/hilfe-kontakt/mailing-listen/abmeldung-liste/
Tipps zu Listenmails: https://wiki.documentfoundation.org/Netiquette/de
Listenarchiv: https://listarchives.libreoffice.org/de/users/
Datenschutzerklärung: https://www.documentfoundation.org/privacy